Evolution of Macros 2

After some testing, I've found out that I hated the last macro setup. While I liked some of the ideas I came up with earlier, I also missed the simplicity of pressing 2 when I wanted to moonfire someone and 2 when I wanted to lifebloom someone, depending on my target.

My new idea is like this, no modifiers first:

1. If I have my mouseover any friendly target, heal it


2. If I have a friendly target, heal it


3. If I have an unfriendly target, hurt it


4. If I press shift, always heal myself


5. If I press ctrl, it tries to hurt or heal the target's target, depending on whether it's harm or helpable (friendly/unfriendly).

I've saved alt for special occasions. One of those might be downranking until WotlK or patch 3.0, whichever introduces the downranking change sooner.

Here's my list of macros, including which keybinding I use on it.

2 Lifebloom/Moonfire

#showtooltip
/cast [modifier:shift, target=player][modifier:ctrl,target=targettarget,help][target=mouseover,help][help]Lifebloom;[modifier:ctrl,target=targettarget,harm][harm]Moonfire

3 Rejuvenation/Insect Swarm

#showtooltip
/cast [modifier:shift, target=player][modifier:ctrl,target=targettarget,help][target=mouseover,help][help]Rejuvenation;[modifier:ctrl,target=targettarget,harm][harm]Insect Swarm

4 Swiftmend/Faerie Fire

#showtooltip
/cast [modifier:shift, target=player][modifier:ctrl,target=targettarget,help][target=mouseover,help][help]Swiftmend;[modifier:ctrl,target=targettarget,harm][harm]Faerie Fire

5 Abolish Poison
Removed Entangling Roots from this button, moved it to it's own button. If I'll spec balance, this is a good place to place a hurting spell.

#showtooltip
/cast [modifier:shift, target=player][modifier:ctrl,target=targettarget,help][target=mouseover,help][help][]Abolish Poison;

6 Remove Curse
Same as above, removed Cyclone. Another hurting balance spell?

#showtooltip
/cast [modifier:shift, target=player][modifier:ctrl,target=targettarget,help][target=mouseover,help][help][]Remove Curse;

Q Healing Touch/Starfire

#showtooltip
/cast [modifier:shift, target=player][modifier:ctrl,target=targettarget,help][target=mouseover,help][help]Healing Touch;[modifier:ctrl,target=targettarget,harm][harm]Starfire

W Regrowth/Wrath

#showtooltip
/cast [modifier:shift, target=player][modifier:ctrl,target=targettarget,help][target=mouseover,help][help]Regrowth;[modifier:ctrl,target=targettarget,harm][harm]Wrath

R Nourish
Saved for Wrath. I also have a "free" space for a harm-ability here, should the need arise... Hm... Soothe Animal? Yeah, like I use that regulary... That is one of the few spells I don't mind looking up in the spellbook each time I use it.

T Entangling Roots
This, and the two following macros, are for focusing and using crowd-control-abilities. If I don't have a focus, focus the target and CC it. If I have a focus, CC it. If I press shift, set this as focus and CC it.

#showtooltip
/clearfocus [modifier:shift][target=focus,noexist][target=focus,dead]
/cast [target=focus,exists]Entangling Roots
/stopmacro [target=focus,exists]
/focus [harm,nodead][target=targettarget,harm,nodead]
/cast [target=focus]Entangling Roots

Y Hibernate

#showtooltip
/clearfocus [modifier:shift][target=focus,noexist][target=focus,dead]
/cast [target=focus,exists]Hibernate
/stopmacro [target=focus,exists]
/focus [harm,nodead][target=targettarget,harm,nodead]
/cast [target=focus]Hibernate

G Cyclone macro

#showtooltip
/clearfocus [modifier:shift][target=focus,noexist][target=focus,dead]
/cast [target=focus,exists]Cyclone
/stopmacro [target=focus,exists]
/focus [harm,nodead][target=targettarget,harm,nodead]
/cast [target=focus]Cyclone

U Tranquility/Innervate
Shift: innervate self. Alt: Innervate my target. No modifier: Tranquility.

#showtooltip
/cast [modifier:shift,target=player][modifier:alt,target=mouseover,help][modifier:alt,help]Innervate; Tranquility
/stopmacro [nomodifier:alt]
/script SendChatMessage("You've been Innervated!","WHISPER",nil, UnitName("target"))

A Barkskin/Nature's Grasp
A special macro. Alt: Nature's Grasp. Shift or not in bear: Barkskin. Reason for this is to avoid shifting out of bear if I hit the button by mistake.

#showtooltip
/cast [modifier:alt]Nature's Grasp;[modifier:shift][nostance:1] Barkskin

H Rebirth/Hurricane
I believe I described this in the last post.

#showtooltip
/cast [target=mouseover,dead,help][dead,help][target=focus,dead,help]Rebirth; Hurricane
/stopmacro [nodead][nohelp]
/script SendChatMessage("Prepare to accept Rebirth.","WHISPER",nil, UnitName("target"))

7 Flight Form/Wolf
Simple macro to get the form that can be used in the outdoor area.

#showtooltip
/stopmacro [flying]
/use [outdoors,noflyable]Black War Wolf
/cast Flight Form

0 Mark of the Wild
Shift to give pink paw to myself, Alt to cast Gift of the Wild, otherwise try mouseover and then my target to give Pink Paw.

#showtooltip
/cast [modifier:alt, help]Gift of the Wild;[modifier:shift, target=player][target=mouseover,help][help][]Mark of the Wild

+ Thorns
Same as the pink paw, except there's no group version of this thing.

#showtooltip
/cast [modifier:shift, target=player][target=mouseover,help][help][]Thorns

Alt-Q NS+HT
A modified version of the classic NS+HT. Should be easy enough to understand.

#showtooltip
/cast Nature's Swiftness
/stopcasting
/cast [modifier:ctrl,target=focustarget,help,nodead][target=mouseover,nodead,help][help][]Healing Touch;

Alt-W Trinket 1
Usually my PVP trinket in PVP.

#showtooltip
/use 13

Alt-R Trinket 2
Often a passive trinket, but can also be a healing-trinket or another emergency-button.

#showtooltip
/use 14

Shift-| Clearfocus
Just in case I need it.

/clearfocus

Other keybindings

| War Stomp
Ctrl-| Nature's Swiftness

Considered moving the latter one, but it's been there for so long it seems to have gotten stuck.

Some keybindings which will be dropped in WotLK or patch 3.0

Alt-2 Moonfire(Rank 1)
Alt-4 Faerie Fire(Rank 1)
Alt-t Entangling Roots(Rank 1)

Some future keybindings (Wrath), only with the right talents:

1 Flourish or Starfall (Wrath)
5 Typhoon (Wrath)

Evolution of Macros 1

Macros are powerful tools. They don't demand memory like addons, are legal in any tournament, and can easily be rewritten if the needs should change.

For quite a while, I've macroed all my usually used buttons to use one spells on friendly targets ([help]) and another spell on unfriendly targets ([harm]). A simple macro like that would be:

#showtooltip
/cast [help] Lifebloom; [harm] Moonfire


Until recently, I've also depended on the addon Clique for healing. It has not yet failed me, but I saw another available option, using the macro for mouseover-actions. Basically, while the mouse is hovering over a target, press a keyboard button and it casts a spell at the target. My former macro above changed to this:

#showtooltip
/cast [target=mouseover, help] Lifebloom; [target=mouseover, harm] Moonfire; [help] Lifebloom; [harm] Moonfire


It didn't take long to discover the disadvangate; It is very easy to have your mouse the wrong place when want to target your... target, and target that target instead. Bummer. The biggest problem was with enemy targets, thus I changed the macro:

#showtooltip
#showtooltip
/cast [target=mouseover, help][help] Lifebloom; [harm] Moonfire


Still not happy. Often when I intend to heal a party member my mouse is hovering over, it's slightly off target, and I end up either casting moonfire on my enemy target (thus dropping out of Tree of Life), or Lifebloom on my friendly target. The latter isn't really a big problem. I avoided the problem of targetting myself with a different macro, bound to shift-(same button). Lifebloom/Moonfire is on 2, thus shift-2 is lifebloom myself:

#showtooltip
/cast [target=player] Lifebloom


But hey, I can include that in the macro! Just need to unbind the button on my keybindings. Less buttons that take up my screen = better.

#showtooltip
/cast [modifier:shift, target=player][target=mouseover, help][help] Lifebloom; [harm] Moonfire


Still doesn't fix the original problem.

Now, yesterday I had another thought. I want my buttons/macros to be reliable, and at the same time easy to use. I thought something in the lines of: I can use the focus. The macros can react differently depending on whether my focus is friendly or unfriendly. But with much thought back and forth, I found that it's slightly a bit unpredictable. I don't want my macros to react differently than what I expect, and I can't always expect that I remember to set focus and for that matter remember what my focus is. Thus, I tried to make macros that were easy to use and reliable.

Idea, evaluate in this order:

1. If I'm my mouse is hovering any friendly target and I press the button, I heal that target.


2. If my target is friendly, heal that.


3. If my target is unfriendly, heal the target's target.

Harmful spells can be fixed with a modifier. Of course it's not as easily accessible as it was before. I'll have to play around and see if I like it.

• Ctrl: Hurt the current target if it's harmable, otherwise hurt the target's target.


• Shift: Still heal myself


• Alt: Heal or hurt the focus, depending on whether it's healable or harmable.

Ideally, I want to set my target as focus if a focus doesn't already exist when I press alt. Unfortunately, I can't. I'm easily breaking the 255-character limit already without it, so I'll try to save space where I can. Especially after commas.


#showtooltip
/cast[modifier:ctrl,harm][modifier:ctrl,target=targettarget,harm][modifier:alt,target=focus,harm]Moonfire;[modifier:shift,target=player][modifier:alt,target=focus,help][target=mouseover,help][help][target=targettarget,help]Lifebloom


There's a solution, though. Move the focus-macro to a different macro/button, namely alt+button. In that case, the main macro can be reduced to:


#showtooltip
/cast[modifier:ctrl,harm][modifier:ctrl,target=targettarget,harm]Moonfire;[modifier:shift,target=player][target=mouseover,help][help][target=targettarget,help]Lifebloom


However, it isn't needed. As far as I have noticed: If WoW finds a keybinding to alt-#, it triggers that button whether or not there's any spell bound to the button. If there's no such keybinding, it triggers the #-button instead, thus possibly triggering a macro. If it's no macro there, it just triggers #. So if you've got no key bound to shift-3 and lifebloom bound to 3, I'll cast lifebloom when I press shift-3.

The alt-macro-thingy could be like this:

#showtooltip
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus
/cast [target=focus, help] Lifebloom; [target=focus, harm] Moonfire


The only "problem" is that you may not always want to loose your focus since you can cast rebirth on him/her! ... But until further, that's not actually something I'd consider a problem. Besides, I've got my smart Rebirth macro already:


#showtooltip
/cast [target=mouseover, dead, help][dead, help][target=focus, dead, help] Rebirth; Hurricane
/stopmacro [nodead][nohelp]
/script SendChatMessage("Prepare to accept Rebirth.","WHISPER",nil, UnitName("target"))


Basically, cast rebirth if the mouseover, target or focus is dead and helpable and whispers them that they'll be ressed. If there's no such target available, cast Hurricane.

I'll post the rest of my macros later.